/*
  Ping
  Generates a brief burst of 40-kHz square waves 50 times per second.
*/
int num_cycles = 20;          // Number of cycles in a ping
unsigned long interval = 50;  // Time interval between pings in ms
unsigned long t0 = 0;         // Starting time of last ping in ms
int state = 0;                // State of pin 3

/*
  Produce num_cycles of a 40-kHz square wave on digital pin 2
*/
void ping() {
  int i;

  for (i = 0; i<num_cycles; i++) {
    digitalWrite(2, HIGH);    // Set digital pin 2 high (i.e. to +5V)
    delayMicroseconds(9);     // Delay for some time (the value 9 was adjusted make the measured high time 12.5us)
    digitalWrite(2, LOW);     // Set digital pin 2 low (i.e. to 0V)
    delayMicroseconds(8);     // Delay for some time
    __asm__("nop\n\t");       // Delay for six instruction cycles ("nop" stands for "no operation", which consumes 
    __asm__("nop\n\t");       //   a single instruction cycle of time)
    __asm__("nop\n\t");
    __asm__("nop\n\t");
    __asm__("nop\n\t");       // The value 8 above and the number of nop instructions were adjusted to make the 
    __asm__("nop\n\t");       //   measured low time 12.5us
  }
}

void setup() {
  pinMode(2, OUTPUT);         // Make digital pin 2 a digital output
  digitalWrite(2, LOW);       // Set digital pin 2 low (i.e. to 0V)
  pinMode(3, OUTPUT);         // Make digital pin 3 a digital output
  digitalWrite(3, LOW);       // Set digital pin 3 low (i.e. to 0V)
}

void loop() {
  unsigned long t;

  t = millis();
  if (t-t0>=interval) {
    t0 = t;
    state = 1-state;          // Toggle state between 0 and 1
    digitalWrite(3, state);   // Make digital pin 3 toggle each time a ping is sent on digital pin 2
    ping();
  }
}